MOH Miscellneous Script Documentation


Contents:
MOH Script Syntax Summary
Moveanim Commands
Anim_attached commands
Model Surface Script Control
PlayerSpawn Stuff
Camera Tutorial
Description of the use of Huddraw set of script commands
Scripting Objectives
Mission Briefing Tutorial
Awarding Medals
Giving and Taking Stuff from the Player
Gun Turrets

switch (expr)
{
label1:
	statement
	...
	statement
	break

label2:
	statement
	...
	statement
	break

case 0:
	statement
	...
	statement
	break	

case 1:
	statement
	...
	statement
	break

default:
	statement
	...
	statement
	break
}

if (expr)
	statement

if (expr)
	statement
else
	statement

if (expr)
{
	statement
	...
	statement
}

if (expr)
{
	statement
	...
	statement
}
else
{
	statement
	...
	statement
}

while (expr)
	statement

while (expr)
{
	statement
	...
	statement
}

local.n = 1
while (local.n <= 10)
{
	println local.n
	local.n++
}

for ( statement1 ; expr ; statement2 )
	statement

for ( statement1 ; expr ; statement2 )
{
	statement
	...
	statement
}

for (local.n = 1; local.n <= 10; local.n++)
{
	println local.n
	local.n++
}

println local.n[10]    // prints the element at position 10 of the local.n array

local.n[1][3] = 10     // sets the element at position (1, 3) of the local.n array equal to 10 (Hash table array)

local.n = hello::world::this::is::a::test::123    // consant array
println local.n[1]     // prints hello
println local.n[7]     // prints 123
println local.n[8]     // results in Script Error: const array index '8' out of range
println local.n[hello]     // results in Script Error: const array index '0' out of range

local.n[hello][world][5] = 23
local.a = local.n[hello]
local.b = local.a[world]
println local.b[5]     // prints 23

for (local.n = 1; local.n <= 10; local.n++)
	println game.stats[game.stats_name[local.n]]    // print out element in game.stats array at position game.stats_name[local.n]

local.a = (a::b)::c
println local.a[1][1]   // prints a
println local.a[1][2]   // prints b
println local.a[2]      // prints c

local.Path1 = makeArray
t1 300 10 200
t2 
t3
t4
t5
t6
t7 NIL 10 200
t8
t9
t10
t11
t12
t13
t14 0 10 200
endArray

println local.Path1[1][2]
println local.Path1[1][3]
println local.Path1[1][4]
println local.Path1[1][5]
println local.Path1[14][1]
println local.Path1[15][1]
end

300
10
200
NIL
t14
NIL

	// $truck is a ScriptModel entity with a tiki that has a drive_and_crash animation
	while (1)
	{
		$truck moveanim drive_and_crash
		$truck waittill animdone
	}

// Main script
$dude script actorthread
end

actorthread:
	self attach $plane "seat01" 1 ( 0 0 0 )
	self exec global/disable_ai.scr

	self anim_attached idle
	self waittill animdone

	self anim_attached standup
	self waittill animdone

	self anim_attached walk
	self waittill animdone

	end

// move the cameras origin to the players position
local.pos = $player.origin + (0 0 64)
$watch_camera movetopos local.pos

// tell the camera to watch the player
// the '0' is to fade in no time at all
// NOTE the ""’s are necessary
$watch_camera watch "$player" 0

// cut causes the camera to transition to its new state immediately
$watch_camera cut

// NOT NEEDED FOR OTHER ENTITIES
// HACK to make the player visible
setcvar cg_3rd_person 1

// cuecamera causes us to switch to a camera
cuecamera $watch_camera

wait 6

println "switching to plane"
// watch the plane
// tell the camera to watch the plane
// the '2' is to switch to our new watch over 2 seconds
// NOTE the ""’s are necessary
$watch_camera watch "$plane" 2

// cut causes the camera to transition to its new state immediately
// we don't want that here so we aren't doing it
//$watch_camera cut

wait 8

println "switching to player"

// NOT NEEDED FOR OTHER ENTITIES
// HACK to make the player invisible again
setcvar cg_3rd_person 0
// cueplayer causes us to switch back to the player
cueplayer

//
// test.scr
//

// add the first objective
waitthread global/objectives.scr::add_objectives 1 2 "Find the first objective." $objective1trigger.origin

// add the second objective
waitthread global/objectives.scr::add_objectives 2 2 "Find the second objective." $objective2trigger.origin

// add the third objective
waitthread global/objectives.scr::add_objectives 3 2 "Find the third objective." $objective3trigger.origin

// add the final objective, though not displayed
waitthread global/objectives.scr::add_objectives 4 1 "Find the final objective." $endleveltrigger.origin

// set the current objective to index #1
waitthread global/objectives.scr::current_objectives 1

// start the thread that waits for objective 1 completion
thread objective1

end


// thread that waits for objective 1 completion
objective1:

// wait for the trigger to be encroached
$objective1trigger waittill trigger

// mark objective 1 as complete
waitthread global/objectives.scr::add_objectives 1 3

// set the current objective to index #2
waitthread global/objectives.scr::current_objectives 2

// start the thread that waits for objective 1 completion
thread objective2

end


// thread that waits for objective 2 completion
objective2:

// wait for the trigger to be encroached
$objective2trigger waittill trigger

// mark objective 2 as complete
waitthread global/objectives.scr::add_objectives 2 3

// set the current objective to index #3
waitthread global/objectives.scr::current_objectives 3

// start the thread that waits for objective 3 completion
thread objective3

end


// thread that waits for objective 3 completion
objective3:

// wait for the trigger to be encroached
$objective3trigger waittill trigger

// disable display of objectives 1,2,3 enable objective 4
waitthread global/objectives.scr::add_objectives 1 1
waitthread global/objectives.scr::add_objectives 2 1
waitthread global/objectives.scr::add_objectives 3 1
waitthread global/objectives.scr::add_objectives 4 2

// set the current objective to index #4
waitthread global/objectives.scr::current_objectives 4

// start the thread that waits for final objective completion
thread objective4

end


// thread that waits for final objective completion
objective4:

// wait for the trigger to be encroached
$endleveltrigger waittill trigger

// mark final objective as complete
waitthread global/objectives.scr::add_objectives 4 3

// transition to next level
exec global/missioncomplete.scr nextlevelmapname bsp2bsp

end

 1:  start:
 2:  
 3:  level waittill prespawn
 4:  drawhud 0
 5:  
 6:  level waittill spawn
 7:  exec global/briefing_save.scr
 8:  
 9:  // spawn the thread that will allow the player to skip the briefing
10:  thread briefingskip
11:  
12:  // prevent the player from trying to move around
13:  $player physics_off
14:  thread freezeplayerview
15:  
16:  //starts music track for mission briefing
17:  $player playsound mb5_music
18:  
19:  $player playsound slide_advance
20:  
21:  showmenu briefing5a 1
22:  
23:  $player playsound mb_501
24:  wait 10
25:  
26:  $player playsound slide_advance
27:  
28:  showmenu briefing5a2 1
29:  hidemenu briefing5a 1
30:  wait 8
31:  
32:  $player playsound slide_advance
33:  
34:  showmenu briefing5a3 1
35:  hidemenu briefing5a2 1
36:  wait 4
37:  
38:  $player playsound slide_advance
39:  
40:  showmenu briefing5b 1
41:  hidemenu briefing5a3 1
42:  wait 8
43:  
44:  $player playsound slide_advance
45:  
46:  showmenu briefing5c 1
47:  hidemenu briefing5b 1
48:  
49:  $player playsound mb_502 wait
50:  $player waittill sounddone
51:  
52:  $player playsound slide_advance
53:  
54:  showmenu briefing5d 1
55:  hidemenu briefing5c 1
56:  
57:  $player playsound mb_503 wait
58:  $player waittill sounddone
59:  
60:  $player playsound slide_advance
61:  
62:  showmenu briefing5e 1
63:  hidemenu briefing5d 1
64:  
65:  $player playsound mb_504 wait
66:  $player waittill sounddone
67:  
68:  goto endbriefing
69:  
70:  end
71:  
72:  endbriefing:
73:  
74:  $player stufftext "spmap m5l1a"
75:  
76:  end
77:  
78:  briefingskip:
79:  
80:      if($player.fireheld)
81:      {
82:          goto endbriefing
83:      }
84:  
85:      // check again next server frame
86:      wait 0.01
87:  
88:      goto briefingskip
89:  
90:  end
91:  
92:  freezeplayerview:
93:  
94:      $player.viewangles = (0 0 0)
95:  
96:      wait 0.01
97:      goto freezeplayerview
98:  
99:  end

if (...)
{
    setcvar g_medal0 "1"
    println "You got a medal!"
}

level.skill = getcvar (skill)

if (level.skill == "0")
{ 
    setcvar "g_eogmedal2" "1" //Bronze Star
}
else if (level.skill == "1")
{
    setcvar "g_eogmedal1" "1" //Silver Star 
}

else if (level.skill == "2")
{ 
    setcvar "g_eogmedal0" "1" //Distinguished Service Cross
}

end

• pistol
• rifle
• smg (for sub-machineguns)
• mg (for machineguns)
• grenades
• shotgun
• heavy (for heavy explosive weapons like the bazooka)

• setPlayerUsable <state>: Sets wether or not a player can use this turret. If the parameter is 0, then player’s will not be able to use it. Any other value will allow player’s to use the turret.
• setAimTarget: this sets an entity for the turret to aim at. It will physically point at its aim target. This will get over ridden when the turret has a user (AI or player)
• clearAimTarget: This clears the aim target set by the use of the setAimTarget command.
• startFiring: Makes the turret start firing. Will be overridden if it has a user.
• stopFiring: Stops the turret’s firing after haven being started by the startFiring command.
• TurnSpeed <speed>: Sets the turn speed of the turret in degrees per second. This applied to both the pitch and yaw speeds. Defaults to 180.
• pitchCaps <maxup> <maxdown>: Sets the caps for the turret’s pitch. The first number is the maximum upwards pitch, and the second is the maximum downwards pitch. Note that upwards pitch is negative, and downwards pitch is positive. The upwards pitch defaults to –45, and the downwards defaults to 45.
• yawCenter <yaw>: Sets the yaw to be considered the center of the turret’s allowed yaw arc. Defaults to the yaw that the turret spawns at.
• maxYawOffset <offset>: Sets the maximum amount that the turret can yaw away from its center yaw direction. Defaults to 180, which allws full 360 degree freedom.
• burstFireSettings <mintime> <maxtime> <mindelay> <maxdelay>: Sets the turret to firing in bursts. Does not apply when the turret has a user. Mintime is the minimum length of a firing burst, maxtime is the maximum time of a firing burst, mindelay is the minimum amount of delay between bursts, and maxdelay is the maximim delay between bursts. To turn off burst mode after having turned it on for a turret, call burstFireSettings with all parameters being 0. Turret’s default to having burst mode turned off.
• firetype <type> : type is a string for what to set the weapon's fire type to. The only two usefull options are "bullet" which makes it fire regular bullets, and "fakebullet", which makes it fire fake bullets that don't actually hurt anything.
• firedelay <time> : Sets the time between each shot in seconds.
• bulletdamage <amount> : Sets the amount of damage the bullet should do. Any amount above 40 makes it count as a rifle round, otherwise it's counted as a pistol round.
• tracerfrequency <count> : Sets the number of bullets between each tracer that's made. It's usually set to 5.